#include "sh/common.hlsl"

/* ========================== *
 * Root signature
 * ========================== */

#define ROOTSIG \
    "RootConstants(num32BitConstants = 16, b0), " \
    "DescriptorTable(SRV(t0, space = 0, numDescriptors = unbounded, flags = DESCRIPTORS_VOLATILE)), " \
    "SRV(t0, space = 1), " \
    \
    "StaticSampler(s0, " \
                  "filter = FILTER_MIN_MAG_MIP_POINT, " \
                  "addressU = TEXTURE_ADDRESS_CLAMP, " \
                  "addressV = TEXTURE_ADDRESS_CLAMP, " \
                  "addressW = TEXTURE_ADDRESS_CLAMP, " \
                  "maxAnisotropy = 1)"

ConstantBuffer<struct sh_ui_constants> g_constants : register(b0);
Texture2D g_textures[] : register(t0, space0);
StructuredBuffer<struct sh_ui_instance> g_instances : register(t0, space1);

SamplerState g_sampler : register(s0);

/* ========================== *
 * Vertex shader
 * ========================== */

struct vs_input {
    DECLS(uint, SV_InstanceID);
    DECLS(uint, SV_VertexID);
};

struct vs_output {
    nointerpolation  DECLS(int, tex_nurid);
    DECLS(float2, uv);
    DECLS(float4, tint_srgb);
    DECLS(float4, SV_Position);
};

SH_ENTRY(ROOTSIG) struct vs_output vs(struct vs_input input)
{
    static const float2 unit_quad_verts[4] = {
        float2(-0.5f, -0.5f),
        float2(0.5f, -0.5f),
        float2(0.5f,  0.5f),
        float2(-0.5f,  0.5f)
    };

    struct sh_ui_instance instance = g_instances[input.SV_InstanceID];
    float2 vert = unit_quad_verts[input.SV_VertexID];
    float2 world_pos = mul(instance.xf, float3(vert, 1)).xy;

    struct vs_output output;
    output.SV_Position = mul(g_constants.projection, float4(world_pos, 0, 1));
    output.tex_nurid = instance.tex_nurid;
    output.uv = instance.uv0 + ((vert + 0.5) * (instance.uv1 - instance.uv0));
    output.tint_srgb = float4_norm_from_uint(instance.tint_srgb);
    return output;
}

/* ========================== *
 * Pixel shader
 * ========================== */

struct ps_input {
    struct vs_output vs;
};

struct ps_output {
    DECLS(float4, SV_Target0);
};

SH_ENTRY(ROOTSIG) struct ps_output ps(struct ps_input input)
{
    struct ps_output output;
    float4 color = input.vs.tint_srgb;

    /* Texture */
    if (input.vs.tex_nurid >= 0) {
        color *= g_textures[NURID(input.vs.tex_nurid)].Sample(g_sampler, input.vs.uv);
    }

    output.SV_Target0 = color;
    return output;
}